Underscore-perl by vti

cpanm http://github.com/vti/underscore-perl/tarball/master

or (for zip archive)

cpanm http://github.com/vti/underscore-perl/zipball/master

use Underscore;

_([3, 2, 1])->sort;

The main differences

All the methods have CamelCase aliases. Use whatever you like. I personally prefer underscores.

Objects are simply hashes, not Perl objects. Maybe objects will be added later.

Of course not everything was ported. Some things don't make any sense for Perl, other are impossible to implement without depending on event loops and async programming.

Implementation details

Most of the functions are just wrappers around built-in functions. Others use List::Util and List::MoreUtils modules.

Numeric/String detection is done the same way JSON::PP does it: by using B hacks.

Boolean values are implemented as overloaded methods, that return numbers or strings depending on the context.

_->true;
_->false;

Object-Oriented and Functional Styles

As original Underscore.js you can use Perl version in either an object-oriented or a functional style, depending on your preference. The following two lines of code are identical ways to double a list of numbers.

_->map([1, 2, 3], sub { my ($n) = @_; $n * 2; });
_([1, 2, 3])->map(sub { my ($n) = @_; $n * 2; });

See original documentation why sometimes object-oriented style is better.

Collection Functions (Arrays or Objects)

each_->each(list, iterator, [context]) Alias: forEach
Iterates over a list of elements, yielding each in turn to an iterator function. The iterator is bound to the context object, if one is passed. Each invocation of iterator is called with three arguments: (element, index, list).

_->each([1, 2, 3], sub { my ($num) = @_; warn $num; });
# warns each number in turn...
_->each({one => 1, two => 2, three => 3} =>
      sub { my ($num, $key) = @_; warn $num; });
# warns each number in turn...

map_->map(list, iterator, [context])
Produces a new array of values by mapping each value in list through a transformation function (iterator).

_->map([1, 2, 3], sub { my ($num) = @_; $num * 3; });
# [3, 6, 9]
_->map({one : 1, two : 2, three : 3} => sub { my ($num, key) = @_; $num * 3; });
# [3, 6, 9]

reduce_->reduce(list, iterator, memo, [context]) Aliases: inject, foldl
Also known as inject and foldl, reduce boils down a list of values into a single value. Memo is the initial state of the reduction, and each successive step of it should be returned by iterator.

my $sum =
  _->reduce([1, 2, 3] => sub { my ($memo, $num) = @_; $memo + $num; }, 0);
# 6

reduceRight_->reduceRight(list, iterator, memo, [context]) Alias: foldr
The right-associative version of reduce.

my $list = [[0, 1], [2, 3], [4, 5]];
my $flat =
  _->reduceRight($list, sub { my ($a, $b) = @_; $a->concat($b); }, []);
# [4, 5, 2, 3, 0, 1]

detect_->detect(list, iterator, [context])
Looks through each value in the list, returning the first one that passes a truth test (iterator). The function returns as soon as it finds an acceptable element, and doesn't traverse the entire list.

my $even =
  _->detect([1, 2, 3, 4, 5, 6] => sub { my ($num) = @_; $num % 2 == 0; });
# 2

select_->select(list, iterator, [context]) Alias: filter
Looks through each value in the list, returning an array of all the values that pass a truth test (iterator).

my $evens =
  _->select([1, 2, 3, 4, 5, 6] => sub { my ($num) = @_; $num % 2 == 0; });
# [2, 4, 6]

reject_->reject(list, iterator, [context])
Returns the values in list without the elements that the truth test (iterator) passes. The opposite of select.

my $odds =
  _->reject([1, 2, 3, 4, 5, 6] => sub { my ($num) = @_; $num % 2 == 0; });
# [1, 3, 5]

all_->all(list, iterator, [context]) Alias: every
Returns true if all of the values in the list pass the iterator truth test.

_->all([_->true, 1, undef, 'yes'] => sub { my ($n) = @_; $n eq 'hello' });
# false

any_->any(list, [iterator], [context]) Alias: some
Returns true if any of the values in the list pass the iterator truth test. Short-circuits and stops traversing the list if a true element is found.

_->any([undef, 0, 'yes', _->false]);
# true

include_->include(list, value) Alias: contains
Returns true if the value is present in the list, using eq to test equality.

_->include([1, 2, 3], 3);
# true

invoke_->invoke(list, methodName, [*arguments])
Calls the method named by methodName on each value in the list. Any extra arguments passed to invoke will be forwarded on to the method invocation.

_->invoke([[5, 1, 7], [3, 2, 1]], 'sort');
# [[1, 5, 7], [1, 2, 3]]

pluck_->pluck(list, propertyName)
A convenient version of what is perhaps the most common use-case for map: extracting a list of property values.

my $stooges = [
    {name => 'moe',   age => 40},
    {name => 'larry', age => 50},
    {name => 'curly', age => 60}
];
_->pluck(stooges, 'name');
# ["moe", "larry", "curly"]

max_->max(list, [iterator], [context])
Returns the maximum value in list. If iterator is passed, it will be used on each value to generate the criterion by which the value is ranked.

my $stooges = [
    {name => 'moe',   age => 40},
    {name => 'larry', age => 50},
    {name => 'curly', age => 60}
];
_->max(stooges, sub { my ($stooge) = @_; $stooge->{age}; });
# {name => 'curly', age => 60};

min_->min(list, [iterator], [context])
Returns the minimum value in list. If iterator is passed, it will be used on each value to generate the criterion by which the value is ranked.

my $numbers = [10, 5, 100, 2, 1000];
_->min($numbers);
# 2

sortBy_->sortBy(list, iterator, [context])
Returns a sorted copy of list, ranked by the results of running each value through iterator.

_->sortBy([1, 2, 3, 4, 5, 6] => sub { my ($num) = @_; sin($num); });
# [5, 4, 6, 3, 1, 2]

groupBy_->groupBy(list, iterator)
Splits a collection into sets, grouped by the result of running each value through iterator.

_->groupBy([1.3, 2.1, 2.4] => sub { my ($num) = @_; floor($num); });
# {1 => [1.3], 2 => [2.1, 2.4]}

sortedIndex_->sortedIndex(list, value, [iterator])
Uses a binary search to determine the index at which the value should be inserted into the list in order to maintain the list's sorted order. If an iterator is passed, it will be used to compute the sort ranking of each value.

_->sortedIndex([10, 20, 30, 40, 50], 35);
# 3

toArray_->toArray(list)
Converts the list (anything that can be iterated over), into a real Array. Useful for transmuting the arguments object.

_->toArray({one => 1, two => 2, three => 3});
# [1, 2, 3]

size_->size(list)
Return the number of values in the list.

_->size({one => 1, two => 2, three => 3});
# 3

Array Functions

first_->first(array, [n]) Alias: head
Returns the first element of an array. Passing n will return the first n elements of the array.

_->first([5, 4, 3, 2, 1]);
# 5

rest_->rest(array, [index]) Alias: tail
Returns the rest of the elements in an array. Pass an index to return the values of the array from that index onward.

_->rest([5, 4, 3, 2, 1]);
# [4, 3, 2, 1]

last_->last(array)
Returns the last element of an array.

_->last([5, 4, 3, 2, 1]);
# 1

compact_->compact(array)
Returns a copy of the array with all falsy values removed. In JavaScript, false, null, 0, "", undefined and NaN are all falsy.

_->compact([0, 1, _->false, 2, '', 3]);
# [1, 2, 3]

flatten_->flatten(array)
Flattens a nested array (the nesting can be to any depth).

_->flatten([1, [2], [3, [[[4]]]]]);
# [1, 2, 3, 4];

without_->without(array, [*values])
Returns a copy of the array with all instances of the values removed. eq is used for the equality test.

_->without([1, 2, 1, 0, 3, 1, 4], 0, 1);
# [2, 3, 4]

union_->union(*arrays)
Computes the union of the passed-in arrays: the list of unique items, in order, that are present in one or more of the arrays.

_->union([1, 2, 3], [101, 2, 1, 10], [2, 1]);
# [1, 2, 3, 101, 10]

intersection_->intersection(*arrays)
Computes the list of values that are the intersection of all the arrays. Each value in the result is present in each of the arrays.

_->intersection([1, 2, 3], [101, 2, 1, 10], [2, 1]);
# [1, 2]

difference_->difference(array, other)
Similar to without, but returns the values from array that are not present in other.

_->difference([1, 2, 3, 4, 5], [5, 2, 10]);
# [1, 3, 4]

uniq_->uniq(array, [isSorted]) Alias: unique
Produces a duplicate-free version of the array, using === to test object equality. If you know in advance that the array is sorted, passing true for isSorted will run a much faster algorithm.

_->uniq([1, 2, 1, 3, 1, 4]);
# [1, 2, 3, 4]

zip_->zip(*arrays)
Merges together the values of each of the arrays with the values at the corresponding position. Useful when you have separate data sources that are coordinated through matching array indexes. If you're working with a matrix of nested arrays, zip.apply can transpose the matrix in a similar fashion.

_->zip(['moe', 'larry', 'curly'], [30, 40, 50], [_->true, _->false, _->false]);
# [["moe", 30, _->true], ["larry", 40, _->false], ["curly", 50, _->false]]

indexOf_->indexOf(array, value, [isSorted])
Returns the index at which value can be found in the array, or -1 if value is not present in the array. Uses the native indexOf function unless it's missing. If you're working with a large array, and you know that the array is already sorted, pass true for isSorted to use a faster binary search.

_->indexOf([1, 2, 3], 2);
# 1

lastIndexOf_->lastIndexOf(array, value)
Returns the index of the last occurrence of value in the array, or -1 if value is not present. Uses the native lastIndexOf function if possible.

_->lastIndexOf([1, 2, 3, 1, 2, 3], 2);
# 4

range_->range([start], stop, [step])
A function to create flexibly-numbered lists of integers, handy for each and map loops. start, if omitted, defaults to 0; step defaults to 1. Returns a list of integers from start to stop, incremented (or decremented) by step, exclusive.

_->range(10);
# [0, 1, 2, 3, 4, 5, 6, 7, 8, 9]
_->range(1, 11);
# [1, 2, 3, 4, 5, 6, 7, 8, 9, 10]
_->range(0, 30, 5);
# [0, 5, 10, 15, 20, 25]
_->range(0, -10, -1);
# [0, -1, -2, -3, -4, -5, -6, -7, -8, -9]
_->range(0);
# []

Function Methods (haha, no confusion!)

bind_->bind(function, object, [*arguments])
Bind a function to an object, meaning that whenever the function is called, the value of this will be the object. Optionally, bind arguments to the function to pre-fill them, also known as currying.

my $func =
  sub { my ($this, $greeting) = @_; $greeting . ': ' . $this->{name} };
$func = _->bind($func, {name => 'moe'}, 'hi');
$func->();
# 'hi: moe'

memoize_->memoize(function, [hashFunction])
Memoizes a given function by caching the computed result. Useful for speeding up slow-running computations. If passed an optional hashFunction, it will be used to compute the hash key for storing the result, based on the arguments to the original function. The default hashFunction just uses the first argument to the memoized function as the key.

my $fibonacci;
$fibonacci = sub {
    my ($n) = @_;
    $n < 2 ? $n : $fibonacci->($n - 1) + $fibonacci->($n - 2);
};
my $fastFibonacci = _->memoize($fibonacci);

once_->once(function)
Creates a version of the function that can only be called one time. Repeated calls to the modified function will have no effect, returning the value from the original call. Useful for initialization functions, instead of having to set a boolean flag and then check it later.

my $initialize = _->once($createApplication);
$initialize->();
$initialize->();
// Application is only created once.

after_->after(count, function)
Creates a version of the function that will only be run after first being called count times. Useful for grouping asynchronous responses, where you want to be sure that all the async calls have finished, before proceeding.

my $renderNotes = _->after(length $notes, $render);
_->each($notes, sub {
    my ($note) = @_;
    $note->asyncSave({success => $renderNotes});
});
// renderNotes is run once, after all notes have saved.

wrap_->wrap(function, wrapper)
Wraps the first function inside of the wrapper function, passing it as the first argument. This allows the wrapper to execute code before and after the function runs, adjust the arguments, and execute it conditionally.

my $hello = sub { my ($name) = @_; "hello: " . $name; };
$hello = _->wrap(
    $hello => sub {
        my ($func) = @_;
        "before, " . $func->("moe") . ", after";
    }
);
$hello->();
# 'before, hello: moe, after'

compose_->compose(*functions)
Returns the composition of a list of functions, where each function consumes the return value of the function that follows. In math terms, composing the functions f(), g(), and h() produces f(g(h())).

my $greet   = sub { my ($name)      = @_; "hi: " . name; };
my $exclaim = sub { my ($statement) = @_; $statement . "!"; };
my $welcome = _->compose($exclaim, $greet);
$welcome->('moe');
# 'hi: moe!'

Object Functions

keys_->keys(object)
Retrieve all the names of the object's properties.

_->keys({one => 1, two => 2, three => 3});
# ["one", "two", "three"]

values_->values(object)
Return all of the values of the object's properties.

_->values({one => 1, two => 2, three => 3});
# [1, 2, 3]

functions_->functions(object) Alias: methods
Returns a sorted list of the names of every method in an object — that is to say, the name of every function property of the object.

_->functions(_);
# ["all", "any", "bind", "bindAll", "clone", "compact", "compose" ...

extend_->extend(destination, *sources)
Copy all of the properties in the source objects over to the destination object. It's in-order, to the last source will override properties of the same name in previous arguments.

_->extend({name => 'moe'}, {age => 50});
# {name => 'moe', age => 50}

defaults_->defaults(object, *defaults)
Fill in missing properties in object with default values from the defaults objects. As soon as the property is filled, further defaults will have no effect.

my $iceCream = {flavor => "chocolate"};
_->defaults($iceCream, {flavor => "vanilla", sprinkles => "lots"});
# {flavor => "chocolate", sprinkles => "lots"}

clone_->clone(object)
Create a shallow-copied clone of the object. Any nested objects or arrays will be copied by reference, not duplicated.

_->clone({name => 'moe'});
# {name => 'moe'};

tap_->tap(object, interceptor)
Invokes interceptor with the object, and then returns object. The primary purpose of this method is to "tap into" a method chain, in order to perform operations on intermediate results within the chain.

_([1,2,3,200])->chain()->
  select(sub { my ($num) = @_; $num % 2 == 0; })->
  tap(sub { warn $_ })->
  map(sub { my ($num) = @_; $num * $num })->
  value();
# [2, 200]
# [4, 40000]

isEmpty_->isEmpty(object)
Returns true if object contains no values.

_->isEmpty([1, 2, 3]);
# false
_->isEmpty({});
# true

isArray_->isArray(object)
Returns true if object is an Array.

_->isArray([1,2,3]);
# true

isFunction_->isFunction(object)
Returns true if object is a Function.

_->isFunction(sub {});
# true

isString_->isString(object)
Returns true if object is a String.

_->isString("moe");
# true

isNumber_->isNumber(object)
Returns true if object is a Number.

_->isNumber(8.4 * 5);
# true

isBoolean_->isBoolean(object)
Returns true if object is either true or false.

_->isBoolean(undef);
# false

isRegExp_->isRegExp(object)
Returns true if object is a RegExp.

_->isRegExp(qr/moe/);
# true

isUndefined_->isUndefined(variable)
Returns true if variable is undefined.

_->isUndefined(undef);
# true

Utility Functions

identity_->identity(value)
Returns the same value that is used as the argument. In math: f(x) = x
This function looks useless, but is used throughout Underscore as a default iterator.

my $moe = {name => 'moe'};
$moe eq _->identity($moe);
# true

times_->times(n, iterator)
Invokes the given iterator function n times.

_(3)->times(sub { $genie->grantWish(); });

mixin_->mixin(object)
Allows you to extend Underscore with your own utility functions. Pass a hash of {name => function} definitions to have your functions added to the Underscore object, as well as the OOP wrapper.

_->mixin(
    {   capitalize => sub {
            my ($string) = @_;
            ucfirst $string;
          }
    }
);
_("fabio")->capitalize();
# "Fabio"

uniqueId_->uniqueId([prefix])
Generate a globally-unique id. If prefix is passed, the id will be appended to it.

_->uniqueId('contact_');
# 'contact_104'

template_->template(templateString, [context])
Compiles templates into functions that can be evaluated for rendering. Useful for rendering complicated bits of HTML from JSON data sources. Template functions can both interpolate variables, using <%= … %>, as well as execute arbitrary Perl code, with <% … %>. When you evaluate a template function, pass in a context object that has properties corresponding to the template's free variables. If you're writing a one-off, you can pass the context object as the second parameter to template in order to render immediately instead of returning a template function.

my $compiled = _->template("hello => <%= name %>");
$compiled->({name => 'moe'});
# "hello: moe"

my $list = "<% _->each($people, sub { my ($name) = @_; %> <li><%= $name %></li> <% }); %>";
_->template($list, {people => ['moe', 'curly', 'larry']});
=> "<li>moe</li><li>curly</li><li>larry</li>"

You can change tags too:

_->templateSettings({interpolate => qr/\{\{(.+?)\}\}/ g});

my $template = _->template("Hello {{ $name }}!");
$template->({name => "Mustache"});
# "Hello Mustache!"

Chaining

chain_(obj)->chain()
Returns a wrapped object. Calling methods on this object will continue to return wrapped objects until value is used.

my $stooges = [
    {name => 'curly', age => 25},
    {name => 'moe',   age => 21},
    {name => 'larry', age => 23}
];
my $youngest = _($stooges)->chain()
  ->sortBy(sub { my ($stooge) = @_; $stooge->{age}; })
  ->map(sub { my ($stooge) = @_; $stooge->{name} . ' is ' . $stooge->{age}; })
  ->first()
  ->value();
# "moe is 21"

value_(obj)->value()
Extracts the value of a wrapped object.

_([1, 2, 3])->value();
# [1, 2, 3]

Credits

Undescore.js authors and contributors.

Author

Viacheslav Tykhanovskyi GitHub, @vtivti.